<?xml version="1.0"?>
<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
	<xsl:output method="text"/>

<xsl:template match="type" xml:space="preserve">
	<xsl:value-of select="@name"/> <xsl:value-of select="@name"/>::Parse(uint8_t * &amp;data) {
		return *((<xsl:value-of select="@stored"/> * &amp;) data)++;
	}
</xsl:template>

<xsl:template match="stack">
</xsl:template>

<xsl:template match="arg">
	object = <xsl:value-of select="@type"/>ObjectFactory::Parse(data);
	<xsl:choose>
		<xsl:when test="@branch">
			flows.push_back(Flow(op,
				offset + object-&gt;num(),
				L"<xsl:value-of select="@name"/>",
				<xsl:choose>
					<xsl:when test="@branch = 'post'">true</xsl:when>
					<xsl:otherwise>false</xsl:otherwise>
				</xsl:choose>
			));
		</xsl:when>
		<xsl:otherwise>
			op-&gt;operator [](L"<xsl:value-of select="@name"/>") = object;
		</xsl:otherwise>
	</xsl:choose>
</xsl:template>

<xsl:template name="variable">
	<xsl:param name="value"/>
	<xsl:choose>
		<xsl:when test="starts-with($value, '@')">op-&gt;operator [](L"<xsl:value-of select="substring($value, 2)"/>")-&gt;num()</xsl:when>
		<xsl:otherwise><xsl:value-of select="$value"/></xsl:otherwise>
	</xsl:choose>
</xsl:template>

<xsl:template match="multi">
	for (int32_t i(<xsl:call-template name="variable"><xsl:with-param name="value" select="@start"/></xsl:call-template>),
				last(<xsl:call-template name="variable"><xsl:with-param name="value" select="@end"/></xsl:call-template>);
		i &lt;= last; ++i)
	{
		<xsl:apply-templates/>
	}
</xsl:template>

<xsl:template match="op">
	case 0x<xsl:value-of select="@code"/>: {
		<!-- <xsl:value-of select="translate(@name, '.', '_')"/>$ &amp;ins =
			*new <xsl:value-of select="translate(@name, '.', '_')"/>$(); -->
		<!-- op = new Operation(L"<xsl:value-of select="/engine/@name"/>:<xsl:value-of select="@name"/>"); -->
        op = new <xsl:value-of select="/engine/@name"/>::<xsl:value-of select="translate(@name, '.', '_')"/>$();
		<xsl:apply-templates/>

		<xsl:if test="not(@stop = 'yes')">
			flows.push_back(Flow(op, data.off(), L"next", false));
		</xsl:if>
	} break;
</xsl:template>

<xsl:template match="strata">
	case 0x<xsl:value-of select="@code"/>: {
		<xsl:call-template name="decode"/>
	} break;
</xsl:template>

<xsl:template name="decode">
	switch (reader.get_u8()) {
		<xsl:apply-templates select="op"/>
		<xsl:apply-templates select="strata"/>
	}
</xsl:template>

<xsl:template match="opcodes">
	<xsl:call-template name="decode"/>
</xsl:template>

<xsl:template match="engine">
#include "stdafx.h"

#include "<xsl:value-of select="@name"/>.h"
#include "theoretic/VObjectFactory.h"

namespace Theoretic {
namespace <xsl:value-of select="@name"/> {

<!--xsl:apply-templates select="datatypes/type"/-->

struct Flow {
	Operation *op;
	int32_t offset;
	std::wstring name;
	bool adjust;

	Flow(Operation *op, int32_t offset, const std::wstring &amp;name, bool adjust) :
		op(op), offset(offset), name(name), adjust(adjust)
	{}
};

typedef std::pair&lt;uint32_t, Operation *&gt; OffsetPair;
typedef std::map&lt;uint32_t, Operation *&gt; OffsetMap;

typedef std::pair&lt;Operation *, uint32_t&gt; WidthPair;
typedef std::map&lt;Operation *, uint32_t&gt; WidthMap;

OpGraph *Engine::Parse(menes::bytebuf &amp;data) {
	std::vector&lt;Flow&gt; flows;
    menes::litreader reader(data);

	OffsetMap offsets;
	WidthMap widths;

	Operation *root = NULL;

    while (reader.more()) {
		uint32_t offset(data.off());

		VObjectPtr object;
		Operation *op = NULL;

		<xsl:apply-templates select="opcodes"/>

		if (root == NULL) root = op;
		offsets.insert(OffsetPair(offset, op));
		widths.insert(WidthPair(op, data.off() - offset));
	}

	for (std::vector&lt;Flow&gt;::iterator flow = flows.begin(); flow != flows.end(); ++flow) {
		int32_t target = flow-&gt;offset;
		if (flow-&gt;adjust) target += widths[flow-&gt;op];
		flow-&gt;op-&gt;operator ()(flow-&gt;name).Append(offsets[target]);
	}

	return new OpGraph(root);
}

} }

</xsl:template>

</xsl:stylesheet>